! Model for selecting Nature Reserves 
 at minimal cost so that the probability that each
 of a number of species survives exceeds some
 threshold.
  This a simplification and variation of a model in
    Camm, J., S. Norman, S. Polasky, and A. Solow(2002),
  "Nature Reserve Site Selection to Maximize Expected Species Covered",
  Operations Research, vol. 50, no. 6, (Nov-Dec), pp. 946-955;
! Keywords: Conservation, Nature reserve, Reserve, Environment, Ecology;
SETS:
 SPECIES;
 RESERVE: COST, Y;
 SXR( SPECIES, RESERVE): PS;
ENDSETS
DATA:
 THRESH = .98; ! Survival threshold;
 SPECIES = 1..5;
! Cost of using reserve j;
  COST = 9   8   3   5    8    7     2   6    4;
! PS(i,j) = Probability SPECIES i survives in RESERVE j if opened;
    PS = 
         1   0   0   1   .5   .26   .42   0    1
        .4   1   1   .2  .7   .1    0    .9    0
         0   1   0   0   .6   .3    0    .1   .09
       .25  .27  1   .6  .55   0    .22  .37  .45
         0  .67  0   .55 .77  .2    0    .52  .63 ;
ENDDATA
 
! Minimize the cost of reserves selected;
  MIN = @SUM(RESERVE(j): COST(j)*Y(j));

! This is a rough linear approximation to the survival probability;
   @FOR( SPECIES(i):
     @SUM( RESERVE(j): PS(i,j)*Y(j)) >= THRESH;
       );

 ! The reserve open variables are 0 or 1;
   @FOR( RESERVE(j): @BIN( Y(j)));