!Illustrating how, when there are alternative optima,
Simplex method chooses an extreme point solution, whereas
Interior Point/Barrier (without crossover) chooses
an interior solution that, loosely speaking, is an average
of all extreme point solutions.
When there are alternative optima, and there are secondary
multi-critera, some users may prefer the unique solution of
the barrier method to the essentially random arbitrary choice
of one of the extreme point optima.
Keywords: Alternative optima, Barrier method, Crossover, Interior point method
Multi-criteria, Simplex method;
SUBMODEL astro:
! This model has 3 alternative extreme point optima;
MAX= 15*a + 30*c + 45*m;
a + 2*c + 3*m <= 120;
a + m <= 60;
c + m <= 50;
ENDSUBMODEL
CALC:
@SET( 'TERSEO',0); ! Output level (0:verb, 1:terse, 2:only errors, 3:none);
! Do some cleanup rounding of output;
@SET( 'PRECIS', 6); ! Precision (in digits) for standard reports;
@SET( 'CUTOFF', 0.1E-6); ! Cutoff(Show as zero) solution values smaller than this;
@WRITE(' Solve with Primal Simplex:', @NEWLINE( 1));
@SET( 'SOLVEL', 1); ! Linear solver (0:LINGO decides,1:primal,2:dual,3:barrier);
@SOLVE( astro);
@WRITE(' Solve with Dual Simplex:', @NEWLINE( 1));
@SET( 'SOLVEL', 2); ! Linear solver (0:LINGO decides,1:primal,2:dual,3:barrier);
@SOLVE( astro);
@WRITE(' Solve with Barrier without crossover:', @NEWLINE( 1));
@SET( 'SOLVEL', 3); ! Linear solver (0:LINGO decides,1:primal,2:dual,3:barrier);
@SET( 'BCROSS', 0); ! Crossover to vertex solution with barrier solver(0:n, 1:y);
@SOLVE( astro);
ENDCALC
|